Generating Pseudo Realistic Clouds In Flash (AS3 + Perlin Noise)

package
{
	import flash.events.Event;
	import flash.display.Sprite;
	import flash.display.MovieClip;
	import flash.display.Bitmap;
	import flash.display.BitmapData;  
	import flash.display.BlendMode;
	import flash.geom.Rectangle;
	import flash.geom.Point;
    import flash.geom.Matrix;
    import flash.filters.ColorMatrixFilter;
	public class Main extends MovieClip
	{
		var h:Number= 525; //Height of area covered by clouds
		var w:Number= 797; // Width
		var dir:Array=[new Point(1,262), new Point(400,262)]; 
		var point:Point=new Point(0,0);
		var rect:Rectangle=new Rectangle(0,0,w,h); // replace the 0s to control how high or low your cloud box appears
		var cd:BitmapData;
		var bd:BitmapData;
		var bmp:Bitmap;
		public var sky:Sprite;
		public var cdF:ColorMatrixFilter;
        public var cdS:Sprite;
        public var cdMx:Matrix;
        public var cdMask:Sprite;
 
		public function Main()
		{
			initFilters(); // This just initializes any filters you want to use.  It is not required, but it makes it easier to separate things out for easy tweaking.
			initCloud(); // This starts our primary function
			return;
		}
 
		function initFilters():void {
			cdF = new ColorMatrixFilter([ // This will adjust the alpha and coloring of the clouds. If you are not used to matrixes, 3 = strength of each color, -200 the respective color's alpha
				3, 0, 0, 0, -300, // Red
				0, 3, 0, 0, -300, // Green
				0, 0, 3, 0, -300, // Blue
				0, 0, 0, 1, 0]); // Alpha
		}
 
		function initCloud():void {
    		cd=new BitmapData(w,h, false, 0 );
			bd=new BitmapData(w,h, false, 0 );
			cdS = new Sprite();
            cdS.addChild(new Bitmap(cd)); // Transfers our clouds to our newly created sprite
            cdS.blendMode = "screen"; // Using overlay will darken the background, but can be used to create an effect like clouds being reflected on glass
			sky.addChild(cdS); // My sky layer contains well a masked sky gradient, if you just want to have your clouds on top of a background you can remove the sky. before addchild.
			addEventListener(Event.ENTER_FRAME, renCloud); // Starts the function that generates cloud data
		}
 
		function renCloud(event:Event):void {
			dir[0].x-= 88.000000E-001; // This will give you control over cloud speed.  + = right to left
			dir[0].y-= 0.000000E-001;
			dir[1].x-= 88.000000E-0011;
			dir[1].y-= 0.000000E-001;
            cdMask = new Sprite();
            cdMx = new Matrix();
            cdMx.createGradientBox(w, h, Math.PI / 2, 0, 0); // This creats a gradient box that will work to give our clouds some depth to them
            cdMask.graphics.beginGradientFill("linear", [0, 0, 0], [0.5, 0.2, 1], [0, 96, 255], cdMx);  // These are the attributes for our gradient box, you can adjust these to scale where your gradient fades out your clouds
            cdMask.graphics.drawRect(0, 0, w, h); // Draws box to contain gradient
			cd.perlinNoise(w-300,h-400,5,Math.random() + 1 * h * 5,true,true,7,true,dir); // These are our actual clouds.  This line will let you change cloud size, octaves (layer depth basically), seed, continous or not, and direction
			cd.applyFilter(cd, cd.rect, new Point(0,0), cdF); // Applying our color matrix filter to fade out the clouds some with alpha, and to adjust the depth of color
			cd.draw(cdMask); // apllies our mask to the clouds
			bd.fillRect(rect, 0x00000000); // I tried not using this method and I got a really uneven motion, so I left it in.... there may be a better way to do this and I just don't know it.
			bd.threshold(cd, rect, point, ">", 0xFFFFFF, 0xFFCCCCCC, 0xFFFFFF, true); // sets the thresholds for the clouds
		}
 	}
 }